ASP通用分页样式函数代码

内容导读

互联网集市收集整理的这篇技术教程文章主要介绍了ASP通用分页样式函数代码，小编现在分享给大家，供广大互联网技能从业者学习和参考。文章包含1598字，纯文字阅读大概需要3分钟。

内容图文

<%
'******************************
'函数：MultiPage(Numbers,Perpage,Curpage,Url_Add)
'参数：Numbers,总记录数；Perpage,每页记录数；Curpage,当前页；Url_Add,当前页其它参数如?action=list&
'作者：阿里西西
'日期：2007/7/15
'描述：ASP通用分页样式函数
'示例：MultiPage(100,10,2,"?action=list&")
'******************************
Function MultiPage(Numbers,Perpage,Curpage,Url_Add)
 CurPage=Int(Curpage)
 Dim URL
 URL=Request.ServerVariables("Script_Name")&Url_Add
 MultiPage=""
 Dim Page,Offset,PageI
 If Int(Numbers)>Int(PerPage) Then
  Page=10
  Offset=2
  Dim Pages,FromPage,ToPage
  If Numbers Mod Cint(Perpage)=0 Then
   Pages=Int(Numbers/Perpage)
  Else
   Pages=Int(Numbers/Perpage)+1
  End If
  FromPage=Curpage-Offset
  ToPage=Curpage+Page-Offset-1
  If Page>Pages Then
   FromPage=1
   ToPage=Pages
  Else
   If FromPage<1 Then
    Topage=Curpage+1-FromPage
    FromPage=1
    If (ToPage-FromPage)<Page And (ToPage-FromPage)<Pages Then ToPage=Page
   ElseIF Topage>Pages Then
    FromPage =Curpage-Pages +ToPage
    ToPage=Pages
    If (ToPage-FromPage)<Page And (ToPage-FromPage)<Pages Then FromPage=Pages-Page+1
   End If
  End If
  MultiPage="<a href='"&Url&"page=1'><<</a>  "
  For PageI=FromPage TO ToPage
   If PageI<>CurPage Then
    MultiPage=MultiPage&"<a href='"&Url&"page="&PageI&"'>["&PageI&"]</a> "
   Else
    MultiPage=MultiPage&"<b>["&PageI&"]</b> "
   End If
  Next
  If Int(Pages)>Int(Page) Then
   MultiPage=MultiPage&" ... <a href='"&Url&"page="&Pages&"'> ["&pages&"] >></a>"
  Else
   MultiPage=MultiPage&"<a href='"&Url&"page="&Pages&"'>>></a>"
  End If
 End If
End Function%>

内容总结

以上是互联网集市为您收集整理的ASP通用分页样式函数代码全部内容，希望文章能够帮你解决ASP通用分页样式函数代码所遇到的程序开发问题。 如果觉得互联网集市技术教程内容还不错，欢迎将互联网集市网站推荐给程序员好友。

内容备注

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 gblab@vip.qq.com 举报，一经查实，本站将立刻删除。

内容手机端

---