首页 / ACCESS / Access 2000 数据库 80 万记录通用快速分页类

Access 2000 数据库 80 万记录通用快速分页类

内容导读

互联网集市收集整理的这篇技术教程文章主要介绍了Access 2000 数据库 80 万记录通用快速分页类，小编现在分享给大家，供广大互联网技能从业者学习和参考。文章包含9517字，纯文字阅读大概需要14分钟。

内容图文

代码本人优化过，测试通过

主要思路: 用一条语句统计(Count)出记录数(而不在查询时获得 RecordCount 属性), 缓存在 Cookies 中, 跳转时就不用再次统计. 使用 ADO 的 AbsolutePage 属性进行页面跳转即可. 为方便调用而写成类, 代码主要地方已有说明

硬件环境: AMD Athlon XP 2600+, 256 DDR
软件环境: MS Windows 2000 Advanced Server + IIS 5.0 + Access 2000 + IE 6.0
测试结果: 初次运行在 250(首页) - 400(末页)毫秒, (记录数缓存后)在页面间跳转稳定在 47 毫秒以下.第1页跳到最后一页不多于 350 毫秒

适用范围: 用于普通分页. 不适用于有较复杂的查询时: 如条件为"[Title] Like ’%最爱%’", 查询的时间大大增加, 就算 Title 字段作了索引也没用. :(

<%
Dim intDateStart
intDateStart = Timer()

Rem ## 打开数据库连接
Rem #################################################################
function f__OpenConn()
Dim strDbPath
Dim connstr
strDbPath = "fenye/db.mdb"
connstr  = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="
connstr  = connstr & Server.MapPath(strDbPath)
Set conn  = Server.CreateObject("Adodb.Connection")
conn.open connstr
End function
Rem #################################################################

Rem ## 关闭数据库连接
Rem #################################################################
function f__CloseConn()
If IsObject(conn) Then
conn.close
End If
Set conn = nothing
End function
Rem #################################################################
Rem 获得执行时间
Rem #################################################################
function getTimeOver(iflag)
Dim tTimeOver
If iflag = 1 Then
tTimeOver = FormatNumber(Timer() - intDateStart, 6, true)
getTimeOver = " 执行时间: " & tTimeOver & " 秒"
Else
tTimeOver = FormatNumber((Timer() - intDateStart) * 1000, 3, true)
getTimeOver = " 执行时间: " & tTimeOver & " 毫秒"
End If
End function
Rem #################################################################
Class Cls_PageView
Private sbooInitState
Private sstrCookiesName
Private sstrPageUrl
Private sstrPageVar
Private sstrTableName
Private sstrFieldsList
Private sstrCondiction
Private sstrOrderList
Private sstrPrimaryKey
Private sintRefresh

Private sintRecordCount
Private sintPageSize
Private sintPageNow
Private sintPageMax

Private sobjConn

Private sstrPageInfo

Private Sub Class_Initialize
Call ClearVars()
End Sub

Private Sub class_terminate()
Set sobjConn = nothing
End Sub

Public Sub ClearVars()
sbooInitState = False
sstrCookiesName = ""
sstrPageUrl = ""
sstrPageVar = "page"
sstrTableName = ""
sstrFieldsList = ""
sstrCondiction = ""
sstrOrderList = ""
sstrPrimaryKey = ""
sintRefresh = 0

sintRecordCount = 0
sintPageSize = 0
sintPageNow = 0
sintPageMax = 0
End Sub

Rem ## 保存记录数的 Cookies 变量
Public Property Let strCookiesName(Value)
sstrCookiesName = Value
End Property

Rem ## 转向地址
Public Property Let strPageUrl(Value)
sstrPageUrl = Value
End Property

Rem ## 表名
Public Property Let strTableName(Value)
sstrTableName = Value
End Property

Rem ## 字段列表
Public Property Let strFieldsList(Value)
sstrFieldsList = Value
End Property

Rem ## 查询条件
Public Property Let strCondiction(Value)
If Value <> "" Then
sstrCondiction = " WHERE " & Value
Else
sstrCondiction = ""
End If
End Property

Rem ## 排序字段, 如: [ID] ASC, [CreateDateTime] DESC
Public Property Let strOrderList(Value)
If Value <> "" Then
sstrOrderList = " ORDER BY " & Value
Else
sstrOrderList = ""
End If
End Property

Rem ## 用于统计记录数的字段
Public Property Let strPrimaryKey(Value)
sstrPrimaryKey = Value
End Property

Rem ## 每页显示的记录条数
Public Property Let intPageSize(Value)
sintPageSize = toNum(Value, 20)
End Property

Rem ## 数据库连接对象
Public Property Let objConn(Value)
Set sobjConn = Value
End Property

Rem ## 当前页
Public Property Let intPageNow(Value)
sintPageNow = toNum(Value, 1)
End Property

Rem ## 页面参数
Public Property Let strPageVar(Value)
sstrPageVar = Value
End Property

Rem ## 是否刷新. 1 为刷新, 其他值则不刷新
Public Property Let intRefresh(Value)
sintRefresh = toNum(Value, 0)
End Property

Rem ## 获得当前页
Public Property Get intPageNow()
intPageNow = singPageNow
End Property

Rem ## 分页信息
Public Property Get strPageInfo()
strPageInfo = sstrPageInfo
End Property

Rem ## 取得记录集, 二维数组或字串, 在进行循环输出时必须用 IsArray() 判断
Public Property Get arrRecordInfo()
If Not sbooInitState Then
Exit Property
End If

Dim rs, sql
sql = "SELECT " & sstrFieldsList & _
" FROM " & sstrTableName & _
sstrCondiction & _
sstrOrderList

Set rs = Server.CreateObject("Adodb.RecordSet")
rs.open sql, sobjConn, 1, 1
If Not(rs.eof or rs.bof) Then
rs.PageSize = sintPageSize
rs.AbsolutePage = sintPageNow
If Not(rs.eof or rs.bof) Then
arrRecordInfo = rs.getrows(sintPageSize)
Else
arrRecordInfo = ""
End If
Else
arrRecordInfo = ""
End If
rs.close
Set rs = nothing
End Property

Rem ## 初始化记录数
Private Sub InitRecordCount()
sintRecordCount = 0
If Not(sbooInitState) Then Exit Sub
Dim sintTmp
sintTmp = toNum(request.Cookies("_xp_" & sstrCookiesName), -1)
If ((sintTmp < 0) Or (sintRefresh = 1))Then
Dim sql, rs
sql = "SELECT COUNT(" & sstrPrimaryKey & ")" & _
" FROM " & sstrTableName & _
sstrCondiction
Set rs = sobjConn.execute(sql)
If rs.eof or rs.bof Then
sintTmp = 0
Else
sintTmp = rs(0)
End If
sintRecordCount = sintTmp

response.Cookies("_xp_" & sstrCookiesName) = sintTmp
Else
sintRecordCount = sintTmp
End If
End Sub

Rem ## 初始化分页信息
Private Sub InitPageInfo()
sstrPageInfo = ""
If Not(sbooInitState) Then Exit Sub

Dim surl
surl = sstrPageUrl
If Instr(1, surl, "?", 1) > 0 Then
surl = surl & "&" & sstrPageVar & "="
Else
surl = surl & "?" & sstrPageVar & "="
End If

If sintPageNow <= 0 Then sintPageNow = 1
If sintRecordCount mod sintPageSize = 0 Then
sintPageMax = sintRecordCount \ sintPageSize
Else
sintPageMax = sintRecordCount \ sintPageSize + 1
End If
If sintPageNow > sintPageMax Then sintPageNow = sintPageMax

If sintPageNow <= 1 then
sstrPageInfo = "首页上一页"
Else
sstrPageInfo = sstrPageInfo & " <a href=""" & surl & "1"">首页</a>"
sstrPageInfo = sstrPageInfo & " <a href=""" & surl & (sintPageNow - 1) & """>上一页</a>"
End If

If sintPageMax - sintPageNow < 1 then
sstrPageInfo = sstrPageInfo & " 下一页末页 "
Else
sstrPageInfo = sstrPageInfo & " <a href=""" & surl & (sintPageNow + 1) & """>下一页</a> "
sstrPageInfo = sstrPageInfo & " <a href=""" & surl & sintPageMax & """>末页</a> "
End If

sstrPageInfo = sstrPageInfo & " 页次：<strong><font color=""#990000"">" & sintPageNow & "</font> / " & sintPageMax & " </strong>"
sstrPageInfo = sstrPageInfo & " 共 <strong>" & sintRecordCount & "</strong> 条记录 <strong>" & sintPageSize & "</strong> 条/页 "
End Sub

Rem ## 长整数转换
Private function toNum(s, Default)
s = s & ""
If s <> "" And IsNumeric(s) Then
toNum = CLng(s)
Else
toNum = Default
End If
End function

Rem ## 类初始化
Public Sub InitClass()
sbooInitState = True
If Not(IsObject(sobjConn)) Then sbooInitState = False
Call InitRecordCount()
Call InitPageInfo()
End Sub
End Class

Dim strLocalUrl
strLocalUrl = request.ServerVariables("SCRIPT_NAME")

Dim intPageNow
intPageNow = request.QueryString("page")

Dim intPageSize, strPageInfo
intPageSize = 30

Dim arrRecordInfo, i
Dim Conn
f__OpenConn
Dim clsRecordInfo
Set clsRecordInfo = New Cls_PageView

clsRecordInfo.strTableName = "[table1]"
clsRecordInfo.strPageUrl = strLocalUrl
clsRecordInfo.strFieldsList = "[ID], [aaaa], [bbbb], [cccc]"
clsRecordInfo.strCondiction = "[ID] < 10000"
clsRecordInfo.strOrderList = "[ID] ASC"
clsRecordInfo.strPrimaryKey = "[ID]"
clsRecordInfo.intPageSize = 20
clsRecordInfo.intPageNow = intPageNow

clsRecordInfo.strCookiesName = "RecordCount"
clsRecordInfo.strPageVar = "page"

clsRecordInfo.intRefresh = 0
clsRecordInfo.objConn = Conn
clsRecordInfo.InitClass

arrRecordInfo = clsRecordInfo.arrRecordInfo
strPageInfo = clsRecordInfo.strPageInfo
Set clsRecordInfo = nothing
f__CloseConn
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>分页测试</title>
<style type="text/css">

</style>
<style type="text/css">

</style>
</head>
<body>
<table width="100%" border="0" cellspacing="0" cellpadding="4">
  <tr>
  <td> <%= strPageInfo%></td>
</tr>
</table>
<div class="PageView">
  <table width="100%" border="0" cellspacing="0" cellpadding="4">
    <tr class="Header">
    <td>ID</td>
    <td>描述</td>
    <td>日期</td>
  </tr>
<%
  If IsArray(arrRecordInfo) Then
   For i = 0 to UBound(arrRecordInfo, 2)
%>
  <tr>
    <td> <%= arrRecordInfo(0, i)%></td>
    <td> <%= arrRecordInfo(1, i)%></td>
    <td> <%= arrRecordInfo(2, i)%></td>
  </tr>
<%
   Next
  End If
%>
</table>
</div>
<table width="100%" border="0" cellspacing="0" cellpadding="4">
  <tr>
  <td> <%= strPageInfo%></td>
</tr>
</table>
<table width="100%" border="0" cellspacing="0" cellpadding="4">
  <tr>
    <td align="center"> <%= getTimeOver(1)%></td>
  </tr>
</table>
</body>
</html>

内容总结

以上是互联网集市为您收集整理的Access 2000 数据库 80 万记录通用快速分页类全部内容，希望文章能够帮你解决Access 2000 数据库 80 万记录通用快速分页类所遇到的程序开发问题。如果觉得互联网集市技术教程内容还不错，欢迎将互联网集市网站推荐给程序员好友。

内容备注

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容，请发送邮件至 gblab@vip.qq.com 举报，一经查实，本站将立刻删除。

内容手机端

扫描二维码推送至手机访问。

本文链接：https://qyyshop.com/info/384778.html

来源：【匿名】

【上一篇】Access 开发人员常犯错误大全【下一篇】多个系统共用一个微信公众号，在上传图片的时候会返回access_token过期，怎么解决？

更多 ►

【Access 2000 数据库 80 万记录通用快速分页类】教程文章相关的互联网学习教程文章

连接本地数据库出现：1045 - Access denied for user 'root'@localhost'(using password:YES) 本人解决方案：【图】

直接上图昨天还是好的今天就不行了，密码是没错的，就是本地的连接不上，Linux上的mysql可以连，网上找各种解决方案，什么权限，什么加一句话，还有这个如果连这个都进不去那就直接重装吧，其实也不大一下就好了，我装了2次，可能是没卸载干净，===记得备份一下数据库文件==首先控制面板卸载mysql服务，然后去 C:\ProgramData下面有个mysql 这个是隐藏文件，点击查看勾选隐藏文件就可以看到了，然后删除，再然后cmd: 输入re...

解决Access连接 accdb 不可识别的数据库格式异常

在Access07之前的数据库后缀名均为*.mdb 而连接字符串写成Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\myFolder\*.mdb ;Persist Security Info=False;　　但是Access07和Access10将后缀名改为了*.accdb。而通过上述连接的话就会报出"不可识别的数据库格式"异常。　　需要注意的是Microsoft.Jet.OLEDB.4.0的Oledb的连接方式是比较老的连接方式，而07以后的Oledb连接方式将改成Microsoft.ACE.OLEDB.12.0。　　改后的连接变成了...

vc访问ACCESS数据库

在现代软件开发中，数据库技术被越来越广泛应用，很多项目都存在着大量的数据需要存储，通常都会采用数据库来存储这些数据。最初，数据库厂商推出一个新的数据库产品时，相应的，他会为程序员提供一套访问该数据库的接口，即API。不同的数据库厂商提供的访问接口是不一样的，这样在使用一个新的数据库时，就要学习一套新的API，当然这就加大了开发数据库的难度，也不利于数据库在软件开发过程中的应用。因此，后来Microsoft就推出了...

SpringAccess数据库(oracle)构造【图】

陈科朝：http://blog.csdn.net/u013474104/article/details/44279309================1.spring 对数据库訪问的支持当我们开发持久层的时候。我们面临着多种选择。比方使用JDBC、Hibernate、java持久化API或其他持久化框架。幸好的是spring可以支持全部这些持久化机制。DAO(data access boject)数据訪问对象，这个名字就非常形象描写叙述了DAO在应用程序中所扮演的角色。DAO提供了数据的读取、写入到数据库中的一种方式。它们应该以...

ManagedDataAccess连数据库【代码】【图】

Oracle官方的托管数据库访问组件，单DLL，Oracle.ManagedDataAccess.dll，不安装Oracle客户端，不区分32/64位，直接引用即可。与非托管程序为Oracle.DataAccess.dll相比，不支持BulkCopy和CustomType等。下载https://www.oracle.com/database/technologies/odac-downloads.html或者nuget 文档https://docs.oracle.com/cd/B19306_01/nav/portal_10.htm https://docs.oracle.com/cd/B19306_01/win.102/b14307/OracleDataReaderC...

java连接数据库失败：java.sql.SQLException: Access denied for user 'root'@'localhost' (using password: YES)【代码】

说一下我的情况：　　1、通过命令行的mysql -uroot -p输入密码可以登录（证明账号和密码正确）　　2、使用最基本的JDBC连接数据库也失败了，报同样的错误信息尝试过　　1、清缓存（包括整个项目的缓存，重新打包发布），电脑和服务器重启了n遍　　2、连接mysql的url中增加编码格式：jdbc_url=jdbc:mysql://127.0.0.1:3306/myDB?useUnicode=true&characterEncoding=utf8&zeroDateTimeBehavior=convertToNull jdbc_username=root j...

【Access2007】修改数据库密码与输入SQL语句进行查询【图】

Access是个不入流的数据库，之所以说他不入流是因为其兼容性，大小等都未达到软件运营的要求，但是某些项目对方要求必须以Access作为数据库，你也是不得不对此了解。Access是个完全图形化操作的数据库，程序猿出来刚到会对此很不适应。因为你不知道怎么修改数据库密码——这还是其次，你根本找不到哪个部分给你输入SQL语句操作数据。毕竟对于程序猿来说，能输入代码操作计算机才是最重要的。一、修改Access2007数据库密码左上角有打...

centos mysql数据库问题：ERROR 1044 (42000): Access denied for user ''@'localhost' to database 'mysql'（转）

问题描述：安装好数据库MySQL，进入mysql，设置号密码后，退出的时候，利用密码无法进入，直接回车后可进入，无法看到数据库mysql，use mysql返回错误：ERROR 1044 (42000): Access denied for user ‘‘@‘localhost‘ to database ‘mysql‘参考地址：ERROR 1044 (42000): Access denied for user ‘‘@‘localhost‘ to database ‘mysql‘@'localhost' to database 'mysql'（转）' ref='nofollow'>centos mysql数据库问题：ERR...

创建ACCESS数据库，并且创建表和数据。重点：关闭ACCESS数据库引用【代码】

///<summary>/// 创建ACCESS数据库，并且创建表和数据///</summary>///<param name="dictTable"></param>///<param name="filePath"></param>///<returns></returns>publicint DataTableToAccess(Dictionary<string, DataTable> dictTable, string filePath){int count = 0;string connStr = string.Format("Provider=Microsoft.Jet.OLEDB.4.0;Data Source={0};Jet OLEDB:Engine Type=5", filePath);try{ADOX.Catalog catalog = ne...

Access数据库从入门到进门(一)【图】

简介 Microsoft Office Access是由微软发布的关系数据库管理系统。它结合了MicrosoftJet Database Engine和图形用户界两项特点，是Microsoft Office的系统程序之一。 Access在很多地方广泛应用，例如小型企业，大公司的部门等。 Access的用途体现在两个方面：一、用来进行数据分析：Access有强大的数据处理、统计分析能力，利用Access的查询功能，可以方便的进行各类汇总、平均等统计。并可灵活设置...

[转载]Unity3D 访问Access数据库【代码】【图】

在开始这个小教程之前呢，其实在网上你已经可以找到相关的资料了，但是我还是要把我自己做练习的一点东西分享出来。写这个教程的主要原因呢，是一个朋友在u3d的官网论坛里，找到了这个demo，但是在他使用的过程中遇到了问题，我看了给他解决掉之后，为了其他朋友不至于发生同类的问题，特在此唠叨一番。在开始主题之前呢，我真的想说，北京的公交太不给力了，我这几天，每次等公交都要一个多小时，直接崩溃中。好，闲话不扯啦！下面...

Access 数据库连接字符串【代码】

<connectionStrings><add name="AccessConnectionString" connectionString="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=|DataDirectory|\AccessDB.mdb" providerName="System.Data.OleDb"/></connectionStrings>static Database db = DatabaseFactory.CreateDatabase("AccessConnectionString"); 原文：http://www.cnblogs.com/valeb/p/4315353.html

PHP数据库链接类(PDO+Access)实例分享

PHP PDO Access链接复制代码代码如下:class DbHelpClass { private $conn; private $qxId; private $ret; function __construct() { $path="../../App_Data/sd#f#45G_!.mdb"; $constr="DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=".realpath($path); $this->conn= new PDO("odbc:$constr") or die ("PDO Connection faild."); } /*...

怎样把ACCESS导入SQL数据库

很多朋友想用SQL2000数据库的编程方法，但是却又苦于自己是学ACCESS的，对SQL只是一点点的了解而已，这里我给大家提供以下参考---将ACCESS转化成SQL2000的方法和注意事项一，首先，我说的是在ACCESS2000，SQL2000之间转换，其他的我也还没有尝试过，希望大家多多试验，肯定是有办法的；二，转换的方法 1，打开”控制面板“下”管理工具“中的”数据库源“； 2，按”添加“添加一个新的数据源，在选择栏里选”Driver do microsoft...

VC 链接Access 数据库插入变量到表【图】

前面介绍：mfc 链接 access 2007 数据库接下来就来说说怎么插入数据到access 2007 数据库（网上找了下，说的有些模糊，直接来看看效果）主要步骤：1 先用sprintf生成SQL语句2 再执行SQL语句就可以了效果如下：主要代码：CString strConn,strDBName;//serv103_serv_link_acces();if(m_pConnection->State) {m_pRecordset.CreateInstance("ADODB.Recordset");//m_pConnection->Close(); ///如果已经打开了连接则关闭它try{int m_id ...

ACCESS - 最热教程

python接口自动化全局变量access_token...解决ubuntu下mysql的'Access denied fo...homebrew 安装问题fatal: unable to ac...PHP学习----Accessdeniedforuserroot@l...WIN7(64位)系统发现数据源ODBC里面没有...sqlmap从入门到精通-第五章-5-1 使用sq...fastadmin微信小程序获取access_token 使用Access-Control-Allow-Origin解决跨...Access denied for user 'root&#39...centos7.2 apache开启.htaccess

首页 / ACCESS / Access 2000 数据库 80 万记录通用快速分页类

Access 2000 数据库 80 万记录通用快速分页类

内容导读

内容图文

内容总结

内容备注

内容手机端

【Access 2000 数据库 80 万记录通用快速分页类】教程文章相关的互联网学习教程文章

连接本地数据库出现：1045 - Access denied for user 'root'@localhost'(using password:YES) 本人解决方案：【图】

解决Access连接 accdb 不可识别的数据库格式异常

vc访问ACCESS数据库

SpringAccess数据库(oracle)构造【图】

ManagedDataAccess连数据库【代码】【图】

java连接数据库失败：java.sql.SQLException: Access denied for user 'root'@'localhost' (using password: YES)【代码】

【Access2007】修改数据库密码与输入SQL语句进行查询【图】

centos mysql数据库问题：ERROR 1044 (42000): Access denied for user ''@'localhost' to database 'mysql'（转）

创建ACCESS数据库，并且创建表和数据。重点：关闭ACCESS数据库引用【代码】

Access数据库从入门到进门(一)【图】

[转载]Unity3D 访问Access数据库【代码】【图】

Access 数据库连接字符串【代码】

PHP数据库链接类(PDO+Access)实例分享

怎样把ACCESS导入SQL数据库

VC 链接Access 数据库插入变量到表【图】

ACCESS - 相关标签

数据库 - 相关标签

ACCESS - 最新教程

ACCESS - 最热教程