在asp中通过getrows实现数据库记录分页的一段代码

内容导读

互联网集市收集整理的这篇技术教程文章主要介绍了在asp中通过getrows实现数据库记录分页的一段代码，小编现在分享给大家，供广大互联网技能从业者学习和参考。文章包含1820字，纯文字阅读大概需要3分钟。

内容图文

代码如下:<%@ Language = VBSCRIPT %> 
<% Option Explicit %> 
<% 
rem 在asp中通过getrows实现数据库记录分页的一段代码 
  Dim iStart, iOffset 
  iStart = Request("Start") 
  iOffset = Request("Offset") 

  if Not IsNumeric(iStart) or Len(iStart) = 0 then 
    iStart = 0 
  else 
    iStart = CInt(iStart) 
  end if 

  if Not IsNumeric(iOffset) or Len(iOffset) = 0 then 
    iOffset = 30 
  else 
    iOffset = Cint(iOffset) 
  end if 

  Response.Write "Viewing " & iOffset & " records starting at record " & iStart & "<BR>" 

  Dim objConn, objRS 
  Set objConn = Server.CreateObject("ADODB.Connection") 
  'objConn.Open "DSN=MP3" 
dim connstr 
dim db 
db="csnjimageman.mdb" 
connstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(""&db&"") 
objconn.Open connstr 

  Set objRS = Server.CreateObject("ADODB.Recordset") 
  objRS.Open "SELECT * FROM imageinfo", objConn 

  Dim aResults 
  aResults = objRS.GetRows 

  objRS.Close 
  Set objRS = Nothing 

  objConn.Close 
  Set objConn = Nothing 


  Dim iRows, iCols, iRowLoop, iColLoop, iStop 
  iRows = UBound(aResults, 2) 
  iCols = UBound(aResults, 1) 

  If iRows > (iOffset + iStart) Then 
    iStop = iOffset + iStart - 1 
  Else 
    iStop = iRows 
  End If 

  For iRowLoop = iStart to iStop 
    For iColLoop = 0 to iCols 
      Response.Write aResults(iColLoop, iRowLoop) & " " 
    Next 
    Response.Write "<BR>" 
  Next   

  Response.Write "<P>" 
  if iStart > 0 then 
    'Show Prev link 
    Response.Write "<A HREF=""GetRows.asp?Start=" & iStart-iOffset & _ 
                   "&Offset=" & iOffset & """>Previous " & iOffset & "</A>" 
  end if 

  if iStop < iRows then 
    'Show Next link 
    Response.Write " <A HREF=""GetRows.asp?Start=" & iStart+iOffset & _ 
                   "&Offset=" & iOffset & """>Next " & iOffset & "</A>" 
  end if 
%> 

内容总结

以上是互联网集市为您收集整理的在asp中通过getrows实现数据库记录分页的一段代码全部内容，希望文章能够帮你解决在asp中通过getrows实现数据库记录分页的一段代码所遇到的程序开发问题。 如果觉得互联网集市技术教程内容还不错，欢迎将互联网集市网站推荐给程序员好友。

内容备注

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 gblab@vip.qq.com 举报，一经查实，本站将立刻删除。

内容手机端