ORACLE SQL 实现IRR的计算（二）

内容导读

互联网集市收集整理的这篇技术教程文章主要介绍了ORACLE SQL 实现IRR的计算（二），小编现在分享给大家，供广大互联网技能从业者学习和参考。文章包含1870字，纯文字阅读大概需要3分钟。

内容图文

上一版实现：https://www.cnblogs.com/Alex-Zeng/p/9334582.html

上一版实现在某些情况下会计算出负值，与Excel的计算有差异。所以修改了实现方法。

实现的具体代码如下：

function IRR_ZEN(p_amount_array in typ_cashflow_array) RETURN NUMBER is
    rtn_err      number := 0;
    irrGuess     number := 0.01; -- default: 10%
    irr          number := 0.0;
    minDistance  number := 1E-15; --iteration: the smaller the distance, the smaller the interpolation
    maxIteration integer := 1000;
  
    wasHi         boolean := false;
    noOfCashFlows integer := 0;
    cashValue     number := 0.0;
    cashFlowStart number := 0.0;
  
    result_value number := 0.0;
  
  BEGIN
    irr           := irrGuess;
    result_value  := -999999;
    noOfCashFlows := p_amount_array.count;
  
    -- business startup costs
    cashFlowStart := p_amount_array(1); 
    
    for i in 1 .. maxIteration loop
      -- calculate cash value with current irr:
      cashValue := cashFlowStart; -- init with startup costs
    
      -- for each cash flow
      for j in 2 .. noOfCashFlows loop
        cashValue := cashValue + p_amount_array(j) / power(1.0 + irr, j-1);
      end loop;
    
      -- cash value is nearly zero
      if (abs(cashValue) < 0.0000000001) then
        -- dbms_output.put_line('abs(cashValue) < 0.0000000001 : '||to_char(cashValue));
        result_value := irr;
        exit;
      end if;
    
      -- adjust irr for next iteration:
      -- cash value > 0 => next irr > current irr
      if (cashValue > 0) then
        if wasHi then
          irrGuess := irrGuess / 2;
        end if;
      
        irr := irr + irrGuess;
      
        if wasHi then
          irrGuess := irrGuess - minDistance;
          wasHi    := false;
        end if;
      
      else
        -- cash value < 0 => next irr < current irr
        irrGuess := irrGuess / 2;
        irr      := irr - irrGuess;
        wasHi    := true;
      end if;
    
      -- estimated result too small to continue => end
      -- calculation
      if (irrGuess <= minDistance) then
        -- dbms_output.put_line('irrGuess <= minDistance : '||to_char(irrGuess));
        result_value := irr;
        exit;
      end if;
    end loop;
  
    return result_value;
  EXCEPTION
    WHEN OTHERS THEN
      dbms_output.put_line(substr(sqlerrm, 1, 640)); 
      return rtn_err;
  END IRR_ZEN;

 

内容总结

以上是互联网集市为您收集整理的ORACLE SQL 实现IRR的计算（二）全部内容，希望文章能够帮你解决ORACLE SQL 实现IRR的计算（二）所遇到的程序开发问题。 如果觉得互联网集市技术教程内容还不错，欢迎将互联网集市网站推荐给程序员好友。

内容备注

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容， 请发送邮件至 gblab@vip.qq.com 举报，一经查实，本站将立刻删除。

内容手机端

---