首页 / C# / c# – 如何从Windows客户端应用程序中使用openAuth？

c# – 如何从Windows客户端应用程序中使用openAuth？

内容导读

互联网集市收集整理的这篇技术教程文章主要介绍了c# – 如何从Windows客户端应用程序中使用openAuth？，小编现在分享给大家，供广大互联网技能从业者学习和参考。文章包含16915字，纯文字阅读大概需要25分钟。

内容图文

我正在考虑将公共API集成到现有的Windows窗体应用程序中. api需要openAuth身份验证.我见过的所有这些例子都是基于网络的应用程序.

如何在客户端应用程序上使用openAUth？

谢谢

解决方法:

这不是最简单的解释,但我为YouTube实施做了这个：

我构建了一个构建消息的ShardOAuth类：

    #Region "Imports"
Imports System.Text
Imports System.Security.Cryptography
#End Region

Public NotInheritable Class SharedOAuth

#Region "Class Declarations"
    Private Const unreservedChars As String = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789-_.~"

    Private Const OAuthVersion As String = "1.0"
    Private Const OAuthParameterPrefix As String = "oauth_"
    Private Const OAuthParameterExclusionPrefix As String = "xoauth_"

    Private Const OAuthConsumerKeyKey As String = "oauth_consumer_key"
    Private Const OAuthCallbackKey As String = "oauth_callback"
    Private Const OAuthVersionKey As String = "oauth_version"
    Private Const OAuthSignatureMethodKey As String = "oauth_signature_method"
    Private Const OAuthSignatureKey As String = "oauth_signature"
    Private Const OAuthTimestampKey As String = "oauth_timestamp"
    Private Const OAuthNonceKey As String = "oauth_nonce"
    Private Const OAuthTokenKey As String = "oauth_token"
    Private Const OAuthTokenSecretKey As String = "oauth_token_secret"
#End Region

#Region "Constructor"
    Private Sub New()
        'prevent construction
    End Sub
#End Region


#Region "Shared Functions"
    Public Shared Function GetSignatureTypeNameFromType(ByVal signatureType As enumerations.OAuthEnumerations.SignatureTypes) As String
        Select Case signatureType
            Case enumerations.OAuthEnumerations.SignatureTypes.HmacSha1
                Return "HMAC-SHA1"
            Case Else
                Return String.Empty
        End Select
    End Function

    Public Shared Function GenerateTimeStamp() As String
        'Implementation of UNIX current UTC time
        Dim _ts As TimeSpan = DateTime.UtcNow - New DateTime(1970, 1, 1, 0, 0, 0, 0)
        Return Convert.ToInt64(_ts.TotalSeconds).ToString(CultureInfo.InvariantCulture)
    End Function

    Public Shared Function GenerateNonce() As String
        'Some random Number
        Return New Random().Next(123400, 9999999).ToString
    End Function

    Public Shared Function UrlEncode(ByVal value As String) As String
        Dim _result As New StringBuilder

        If (String.IsNullOrEmpty(value)) Then
            Return value
        End If

        For Each _symbol As Char In value
            If unreservedChars.IndexOf(_symbol) <> -1 Then
                _result.Append(_symbol)
            Else
                _result.Append(String.Format("%{0}", String.Format("{0:X2}", Asc(_symbol))))
            End If
        Next

        Return _result.ToString
    End Function

    ''' <summary>
    '''Generates a signature using the specified signatureType 
    '''    </summary>       
    '''    <param name="url">The full url that needs to be signed including its non OAuth url parameters</param>
    '''    <param name="consumerKey">The consumer key</param>
    '''    <param name="consumerSecret">The consumer seceret</param>
    '''    <param name="token">The token, if available. If not available pass null or an empty string</param>
    '''    <param name="tokenSecret">The token secret, if available. If not available pass null or an empty string</param>
    '''    <param name="httpMethod">The http method used. Must be a valid HTTP method verb (POST,GET,PUT, etc)</param>
    '''   <param name="signatureType">The type of signature to use</param>
    '''   <returns>A base64 string of the hash value</returns>
    Public Shared Function GenerateSignature(ByVal url As Uri, ByVal consumerKey As String, ByVal consumerSecret As String, ByVal token As String, ByVal tokenSecret As String, ByVal httpMethod As String, ByVal timeStamp As String, ByVal nonce As String, ByVal signatureType As enumerations.OAuthEnumerations.SignatureTypes, ByRef normalizedUrl As String, ByRef normalizedRequestParameters As String) As String
        normalizedUrl = String.Empty
        normalizedRequestParameters = String.Empty

        Dim _signatureBase As String
        Dim _hash As HMACSHA1

        Select Case signatureType
            Case enumerations.OAuthEnumerations.SignatureTypes.HmacSha1
                _signatureBase = GenerateSignatureBase(url, consumerKey, token, tokenSecret, httpMethod, timeStamp, nonce, enumerations.OAuthEnumerations.SignatureTypes.HmacSha1, normalizedUrl, normalizedRequestParameters)

                Dim _sb As New StringBuilder
                With _sb
                    .Append(UrlEncode(consumerSecret))
                    .Append("&")

                    If (String.IsNullOrEmpty(tokenSecret)) Then
                        .Append("")
                    Else
                        .Append(UrlEncode(tokenSecret))
                    End If
                End With

                _hash = New HMACSHA1
                _hash.Key = Encoding.ASCII.GetBytes(_sb.ToString)

                Return GenerateSignatureUsingHash(_signatureBase, _hash)

            Case Else
                Throw New NotImplementedException

        End Select
    End Function

    Public Shared Function GenerateSignatureUsingHash(ByVal signatureBase As String, ByVal hash As HashAlgorithm) As String
        Return ComputeHash(hash, signatureBase)
    End Function

    Public Shared Function GenerateSignatureBase(ByVal url As Uri, ByVal consumerKey As String, ByVal token As String, ByVal tokenSecret As String, ByVal httpMethod As String, ByVal timeStamp As String, ByVal nonce As String, ByVal signatureType As enumerations.OAuthEnumerations.SignatureTypes, ByRef normalizedUrl As String, ByRef normalizedRequestParameters As String) As String
        Dim _SignatureTypeName As String = GetSignatureTypeNameFromType(signatureType)

        If String.IsNullOrEmpty(token) Then
            token = String.Empty
        End If

        If String.IsNullOrEmpty(tokenSecret) Then
            tokenSecret = String.Empty
        End If

        If String.IsNullOrEmpty(consumerKey) Then
            Throw New ArgumentNullException("consumerKey")
        End If

        If String.IsNullOrEmpty(httpMethod) Then
            Throw New ArgumentNullException("httpMethod")
        End If

        If String.IsNullOrEmpty(_SignatureTypeName) Then
            Throw New ArgumentNullException("SignatureType")
        End If

        normalizedUrl = String.Empty
        normalizedRequestParameters = String.Empty

        Dim _params As List(Of QueryParameter) = getqueryparameters(url.Query)

        With _params
            .Add(New QueryParameter(OAuthVersionKey, OAuthVersion))
            .Add(New QueryParameter(OAuthNonceKey, nonce))
            .Add(New QueryParameter(OAuthTimestampKey, timeStamp))
            .Add(New QueryParameter(OAuthSignatureMethodKey, _SignatureTypeName))
            .Add(New QueryParameter(OAuthConsumerKeyKey, consumerKey))

            If Not (String.IsNullOrEmpty(token)) Then
                .Add(New QueryParameter(OAuthTokenKey, token))
            End If

            .Sort(New QueryParameterComparer)
        End With

        normalizedUrl = String.Format("{0}://{1}", url.Scheme, url.Host)

        If Not ((url.Scheme = "http" AndAlso url.Port = 80) OrElse (url.Scheme = "https" AndAlso url.Port = 443)) Then
            normalizedUrl = String.Format("{0}:{1}", normalizedUrl, url.Port)
        End If

        normalizedUrl = String.Format("{0}{1}", normalizedUrl, url.AbsolutePath)

        normalizedRequestParameters = NormalizeRequestParameters(_params)

        Dim _sb As New StringBuilder
        With _sb
            .AppendFormat(CultureInfo.InvariantCulture, "{0}&", httpMethod.ToUpper)
            .AppendFormat(CultureInfo.InvariantCulture, "{0}&", UrlEncode(normalizedUrl))
            .AppendFormat(CultureInfo.InvariantCulture, "{0}", UrlEncode(normalizedRequestParameters))
        End With

        Return _sb.ToString

    End Function
#End Region

#Region "Private Methods"
    Private Shared Function ComputeHash(ByVal hashAlgorithm As HashAlgorithm, ByVal data As String) As String
        If hashAlgorithm Is Nothing Then
            Throw New ArgumentNullException("hashAlgorithm")
        End If

        If String.IsNullOrEmpty(data) Then
            Throw New ArgumentNullException("data")
        End If

        Dim _dataBuffer As Byte() = Encoding.ASCII.GetBytes(data)
        Dim _hashBytes As Byte() = hashAlgorithm.ComputeHash(_dataBuffer)

        Return Convert.ToBase64String(_hashBytes)
    End Function


    Private Shared Function NormalizeRequestParameters(ByVal parameters As IList(Of QueryParameter)) As String

        Dim _p As QueryParameter
        Dim _sb As New StringBuilder

        For i As Integer = 0 To parameters.count - 1
            _p = parameters(i)
            _sb.AppendFormat(CultureInfo.InvariantCulture, "{0}={1}", _p.Name, _p.Value)

            If i < parameters.count - 1 Then
                _sb.Append("&")
            End If
        Next

        Return _sb.ToString

    End Function

    Private Shared Function GetQueryParameters(ByVal parameters As String) As List(Of QueryParameter)
        If (parameters.StartsWith("?")) Then
            parameters = parameters.Remove(0, 1)
        End If

        Dim _result As New List(Of QueryParameter)
        Dim _p As String() = parameters.Split("&"c)

        Dim _temp As String()

        If Not (String.IsNullOrEmpty(parameters)) Then

            For Each s As String In _p
                If Not (String.IsNullOrEmpty(s)) AndAlso Not (s.StartsWith(OAuthParameterExclusionPrefix)) Then 'AndAlso (s.StartsWith(OAuthParameterPrefix)) Then
                    If s.IndexOf("=") > -1 Then
                        _temp = s.Split("="c)
                        _result.Add(New QueryParameter(_temp(0), _temp(1)))
                    Else
                        _result.Add(New QueryParameter(s, String.Empty))
                    End If
                End If

            Next

        End If

        Return _result

    End Function
#End Region


End Class

然后使用这些较低级别的函数来构建和解析OAuth消息

Public MustInherit Class BaseOAuth
    Inherits BaseAccess

#Region "Class Declarations"
    Protected Const CONSUMER_KEY As String = "anonymous"
    Protected Const CONSUMER_SECRET As String = "anonymous"

    Protected Const SCOPEURL As String = "http://gdata.youtube.com"  '

    Protected m_FeedCollection As ArrayList
#End Region

#Region "Constructor"
    Public Sub New()
        MyBase.new()
    End Sub

    Public Sub New(ByVal context As Common.Statefulogic.Context)
        MyBase.new(context)
    End Sub
#End Region

#Region "Public Properties"

#End Region

#Region "Private Functions"

#End Region

#Region "Public Methods"
    Public Function SignCommandUrl(ByVal commandUrl As String) As String
        Return SignCommandUrl(commandUrl, Nothing, Nothing)
    End Function

    Public Function SignCommandUrl(ByVal commandUrl As String, ByVal overrideToken As String, ByVal overrideTokenSecret As String) As String
        Dim _commandUri = New Uri(commandUrl)
        Dim _oAuthSignature As String
        Dim _oAuthTimeStamp As String = SharedOAuth.GenerateTimeStamp
        Dim _oAuthNOnce As String = SharedOAuth.GenerateNonce
        Dim _oAuth_normalized_url As String = String.Empty
        Dim _oAuth_normalized_params As String = String.Empty

        If Not (String.IsNullOrEmpty(overrideToken)) OrElse Not (String.IsNullOrEmpty(overrideTokenSecret)) Then
            _oAuthSignature = SharedOAuth.GenerateSignature(_commandUri, CONSUMER_KEY, CONSUMER_SECRET, overrideToken, overrideTokenSecret, "GET", _oAuthTimeStamp, _oAuthNOnce, enumerations.OAuthEnumerations.SignatureTypes.HmacSha1, _oAuth_normalized_url, _oAuth_normalized_params)
        Else

            If MasterAccessToken Is Nothing Then
                _oAuthSignature = SharedOAuth.GenerateSignature(_commandUri, CONSUMER_KEY, CONSUMER_SECRET, String.Empty, String.Empty, "GET", _oAuthTimeStamp, _oAuthNOnce, enumerations.OAuthEnumerations.SignatureTypes.HmacSha1, _oAuth_normalized_url, _oAuth_normalized_params)
            Else
                _oAuthSignature = SharedOAuth.GenerateSignature(_commandUri, CONSUMER_KEY, CONSUMER_SECRET, SharedOAuth.UrlEncode(MasterAccessToken.Token), MasterAccessToken.TokenSecret, "GET", _oAuthTimeStamp, _oAuthNOnce, enumerations.OAuthEnumerations.SignatureTypes.HmacSha1, _oAuth_normalized_url, _oAuth_normalized_params)
            End If
        End If

        'Get a token
        Dim _sb As New System.Text.StringBuilder
        With _sb
            .Append(_oAuth_normalized_url)
            .Append("?")
            .Append(_oAuth_normalized_params)
            .Append("&")
            .Append("oauth_signature")
            .Append("=")
            .Append(SharedOAuth.UrlEncode(_oAuthSignature))
        End With

        Return _sb.ToString
    End Function

    Public Function BuildPostHeader(ByVal commandUrl As String) As String
        Dim _commandUri = New Uri(commandUrl)
        Dim _oAuthTimeStamp As String = SharedOAuth.GenerateTimeStamp
        Dim _oAuthNOnce As String = SharedOAuth.GenerateNonce
        Dim _oAuth_normalized_url As String = String.Empty
        Dim _oAuth_normalized_params As String = String.Empty
        Dim _oAuthSignature As String

        If MasterAccessToken Is Nothing Then
            _oAuthSignature = SharedOAuth.GenerateSignature(_commandUri, CONSUMER_KEY, CONSUMER_SECRET, String.Empty, String.Empty, "POST", _oAuthTimeStamp, _oAuthNOnce, enumerations.OAuthEnumerations.SignatureTypes.HmacSha1, _oAuth_normalized_url, _oAuth_normalized_params)
        Else
            _oAuthSignature = SharedOAuth.GenerateSignature(_commandUri, CONSUMER_KEY, CONSUMER_SECRET, SharedOAuth.UrlEncode(MasterAccessToken.Token), MasterAccessToken.TokenSecret, "POST", _oAuthTimeStamp, _oAuthNOnce, enumerations.OAuthEnumerations.SignatureTypes.HmacSha1, _oAuth_normalized_url, _oAuth_normalized_params)
        End If


        Dim _sb As New System.Text.StringBuilder
        With _sb
            .Append("Authorization: OAuth oauth_version=""1.0"", ")
            .AppendFormat("oauth_nonce=""{0}"", ", _oAuthNOnce)
            .AppendFormat("oauth_timestamp=""{0}"", ", _oAuthTimeStamp)
            .AppendFormat("oauth_consumer_key=""{0}"", ", CONSUMER_KEY)
            .AppendFormat("oauth_token=""{0}"", ", MasterAccessToken.Token)
            .Append("oauth_signature_method=""HMAC-SHA1"", ")
            .AppendFormat("oauth_signature=""{0}""", _oAuthSignature)
        End With

        Return _sb.ToString
    End Function

    Public Shared Function PostRequestReturnCollection(ByVal commandUrl As String) As NameValueCollection
        Dim _nameValCollection As NameValueCollection

        Dim _request As HttpWebRequest = CType(WebRequest.Create(commandUrl), HttpWebRequest)

        Using _response As HttpWebResponse = CType(_request.GetResponse, HttpWebResponse)
            Using _reader As TextReader = New StreamReader(_response.GetResponseStream)
                _nameValCollection = HttpUtility.ParseQueryString(_reader.ReadToEnd)
            End Using
        End Using

        Return _nameValCollection
    End Function
#End Region

End Class

最后打电话来获取OAuth令牌..

Public Function RequestApplicationAccess() As TokenParams
    Dim _oAuthCallbackConfirmed As Boolean
    Dim _oAuthTokenUrl As String
    Dim _oauth_Authenticate_Page As String
    Dim _oAuthtokendataCollection As NameValueCollection
    Dim _request As HttpWebRequest

    Dim _oauth_token As String = String.Empty
    Dim _oauth_token_secret As String = String.Empty
    Dim _oauth_verifier As String = String.Empty

    m_CallbackSite = "http://www.previewthebestof.co.uk/_services/googleauth.aspx"

    'Generate a signature
    Dim _RequestUrl As String = "https://www.google.com/accounts/OAuthGetRequestToken"
    _oAuthTokenUrl = SignCommandUrl(String.Format("{0}?scope={1}&oauth_callback={2}&xoauth_displayname={3}", _RequestUrl, SharedOAuth.UrlEncode(SCOPEURL), SharedOAuth.UrlEncode(m_CallbackSite), SharedOAuth.UrlEncode(APPDISPLAYNAME)))

    _oAuthtokendataCollection = PostRequestReturnCollection(_oAuthTokenUrl)

    _oauth_token = _oAuthtokendataCollection.Item("oauth_token")
    _oauth_token_secret = _oAuthtokendataCollection.Item("oauth_token_secret")

    If _oAuthtokendataCollection.Count = 3 Then
        _oAuthCallbackConfirmed = CType(_oAuthtokendataCollection.Item("oauth_callback_confirmed"), Boolean)
    End If

    If String.IsNullOrEmpty(_oauth_token) OrElse String.IsNullOrEmpty(_oauth_token_secret) Then
        Throw New N5.Common.ExceptionManager.N5Exception("Cannot get an authentication token (_oauth_token or _oauth_token_secret is blank)")
    End If

    '----------------------------------------------------
    'Write the token to the users profile
    m_Context.UserObject.SetUserAuthenticationTokens(_oauth_token, String.Empty, String.Empty, String.Empty)

    '-----------------------------------------------------
    'Authorize the token
    _RequestUrl = "https://www.google.com/accounts/OAuthAuthorizeToken"

    _oAuthTokenUrl = String.Format("{0}?oauth_token={1}", _RequestUrl, SharedOAuth.UrlEncode(_oauth_token))

    _request = CType(WebRequest.Create(_oAuthTokenUrl), HttpWebRequest)
    Using _response = CType(_request.GetResponse, HttpWebResponse)
        Using _reader As TextReader = New StreamReader(_response.GetResponseStream)
            _oauth_Authenticate_Page = _reader.ReadToEnd
        End Using
    End Using

    If Not (_oauth_Authenticate_Page.ToLower.Contains("<html>")) Then
        Throw New N5.Common.ExceptionManager.N5Exception("AuthToken Respose does not contain a webpage")
    End If

    'Response contains html, which is the youtube authentication page - need to show this to the user 
    'write to temp file
    Dim _tempFileName As String = IO.Path.Combine(My.Computer.FileSystem.SpecialDirectories.Temp, String.Concat(FilenameUtilities.GetRandomFilename, ".htm"))
    Using _tempFile As New StreamWriter(_tempFileName)
        _tempFile.Write(_oauth_Authenticate_Page)
    End Using

    'Load a browser form and navigate to the file just created.
    Using _browser As New BasePopupBrowser
        With _browser
            .WindowState = FormWindowState.Maximized
            .AutoCloseText = "<H1>OAuth Token Authorised</H1>"
            .CheckForAutoCloseText = True
            .NavigateTo(New System.Uri(_tempFileName))
        End With
    End Using

    'Clean up the tempfile
    My.Computer.FileSystem.DeleteFile(_tempFileName)

    '------------------------------------------------------
    'Check the db for a request_token - did the user press authorise?
    m_Context.UserObject.RefreshUserAuthenticationTokens()
    Dim _dv As DataView = m_Context.UserObject.AuthenticationTokensDataView
    _dv.RowFilter = "TokenName='YouTubeAuthVerifier'"

    If _dv.Count > 0 Then
        _oauth_verifier = _dv(0)("Value").ToString
    End If

    If String.IsNullOrEmpty(_oauth_verifier) Then
        'We didnt get a verification token back, chances are the user pressed reject, Doh!
        Return Nothing
    End If

    '---------------------------------------------------------
    'Now we need to exchange the request token for an access token
    _RequestUrl = String.Format("https://www.google.com/accounts/OAuthGetAccessToken?oauth_verifier={0}", SharedOAuth.UrlEncode(_oauth_verifier))

    _oAuthTokenUrl = SignCommandUrl(_RequestUrl, _oauth_token, _oauth_token_secret)

    _oAuthtokendataCollection = PostRequestReturnCollection(_oAuthTokenUrl)

    _oauth_token = _oAuthtokendataCollection.Item("oauth_token")
    _oauth_token_secret = _oAuthtokendataCollection.Item("oauth_token_secret")

    m_Context.UserObject.SetUserAuthenticationTokens(String.Empty, String.Empty, _oauth_token, _oauth_token_secret)

    Return New TokenParams(_oauth_token, _oauth_token_secret)
End Function

内容总结

以上是互联网集市为您收集整理的c# – 如何从Windows客户端应用程序中使用openAuth？全部内容，希望文章能够帮你解决c# – 如何从Windows客户端应用程序中使用openAuth？所遇到的程序开发问题。如果觉得互联网集市技术教程内容还不错，欢迎将互联网集市网站推荐给程序员好友。

内容备注

版权声明：本文内容由互联网用户自发贡献，该文观点与技术仅代表作者本人。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如发现本站有涉嫌侵权/违法违规的内容，请发送邮件至 gblab@vip.qq.com 举报，一经查实，本站将立刻删除。

内容手机端

扫描二维码推送至手机访问。

本文链接：https://qyyshop.com/info/965655.html

来源：【匿名】

【上一篇】c# – 如何运行只有NotifyIcon的“空”Windows应用程序？【下一篇】assemblyinfo.csC#Assembly类访问程序集信息

更多 ►

【c# – 如何从Windows客户端应用程序中使用openAuth？】教程文章相关的互联网学习教程文章

C# WinForm应用程序降低系统内存占用方法总结【代码】

这篇文章主要介绍了C# WinForm应用程序降低系统内存占用方法总结,本文总结了9个方法,同时给出了一个定期清理执行垃圾回收代码,需要的朋友可以参考下背景：微软的 .NET FRAMEWORK 现在可谓如火如荼了。但是，.NET 一直所为人诟病的就是“胃口太大”，狂吃内存，虽然微软声称 GC 的功能和智能化都很高，但是内存的回收问题，一直存在困扰，尤其是 winform 程序，其主要原因是因为.NET程序在启动时，是需要由JIT动态编译并加载的，这...

C#通过窗体应用程序操作数据库（增删改查）【代码】【图】

为了体现面向对象的思想，我们把“增删改查”这些函数封装到一个数据库操作类里；为了便于窗体程序与数据库之间进行数据交互，我们建一个具有数据库行数据的类，通过它方便的在窗体程序与数据库之间传输数据；我们新建一个文件夹，把这两个类放在这个文件夹（App）里，以后，把命名空间写上就可以使用这两个类了。为了便于窗体程序与数据库之间进行数据交互，我们建一个具有数据库行数据的类，通过它方便的在窗体程序与数据库之间传...

应用程序使用统计信息 – .NET CORE(C#) WPF界面设计【代码】

原文:应用程序使用统计信息 – .NET CORE(C#) WPF界面设计应用程序使用统计信息 - .NET CORE(C#) WPF界面设计首发文章地址：https://dotnet9.com/10546.html关键功能点抽屉式菜单圆形进度条Demo演示：1. 新建项目使用 VS 2019 的 .NET Core 3.1 WPF 项目模板，创建名为 “MobileAppUsageDashboardCore” 的项目，NuGet 引入 MaterialDesign 的两个库 MaterialDesignThemes 和 MaterialDesignColors，整个项目工程文件如下：<Projec...

C# 控制台应用程序从外部传参运行和调试【代码】【图】

参考:/*十有三博客*/新建一个用于演示的控制台应用程序项目,然后在Program.cs的入口Main方法里编写如下代码foreach (var arg in args) {Console.WriteLine(arg); } Console.ReadKey();staticvoid Main(string[] args) {foreach (var arg in args){Console.WriteLine(arg);}Console.ReadKey(); }这段代码最后会输出所有传入控制台的参数，调试和运行的方法有两种，一种是设置Visual Studio项目在启动调试时的命令行参数，另外一种是...

【自动化GUI自动化】C#Windows应用程序识别计算器【代码】

一、代码如下#include <stdio.h> #include <stdlib.h> #include <windows.h>int main(int argc, char *argv[]) {//printf("成功");//printf("成功");//printf("成功");HWND windowHandle, controlHandle;char result[10];windowHandle= FindWindow(NULL, "Calculator");//printf(windowHandle);while(windowHandle == NULL) {printf("未找到计算器，请先启动........\n");Sleep(2000);windowHandle= FindWindow(NULL, "Calculator"...

C#获取当前应用程序所在路径及环境变量

一、获取当前文件的路径string str1=Process.GetCurrentProcess().MainModule.FileName;//可获得当前执行的exe的文件名。 string str2=Environment.CurrentDirectory;//获取和设置当前目录（即该进程从中启动的目录）的完全限定路径。(备注:按照定义，如果该进程在本地或网络驱动器的根目录中启动，则此属性的值为驱动器名称后跟一个尾部反斜杠（如“C:\”）。如果该进程在子目录中启动，则此属性的值为不带尾部反斜杠的驱动器和子...

C# MVC中按照业务创建多模块web应用程序（DAL、BLL、UI按照业务模块拆分）【图】

C# MVC中按照业务创建多模块web应用程序（DAL、BLL、UI按照业务模块拆分）如果想要UI层根据业务进行模块划分，UI层发布的时候能达到UI层根据业务单独打包成dll文件，可以在解决方案中将DataObj、DAL、BLL、UI均放在解决方案文件夹下：1、DataObj根据业务按照模块建立对应的类库，发布的时候各个业务模块的DataObj.dll分开，以减低耦合度；注意生成文件的位置置于UI层（含页面的UI类库）下的bin目录下；2、DAL根据业务按照模块...

应用程序在状态栏展示时间（C#）

private DispatcherTimer _timer; private void SetTimeElaspInStatusBar() { try { _timer = new DispatcherTimer(); _timer.Tick += (sender, e) => { DateTime dtNow = DateTime.Now; TimeSpan interval = dtNow - _enterSystemTime; this.barElapsedTime.C...

C#取得控制台应用程序的根目录方法判断文件夹是否存在，不存在就创建【图】

取得控制台应用程序的根目录方法1：Environment.CurrentDirectory 取得或设置当前工作目录的完整限定路径2：AppDomain.CurrentDomain.BaseDirectory 获取基目录，它由程序集冲突解决程序用来探测程序集取得WinForm应用程序的根目录方法1：Environment.CurrentDirectory.ToString();//获取或设置当前工作目录的完全限定路径2：Application.StartupPath.ToString();//获取启动了应用程序的可执行文件的路径，不包括可执行文件的名称...

c#-在WCF和ASP .NET应用程序(.NET 3.5)中都可用的缓存

我需要可以同时从WCF和ASP .NET应用程序中使用的缓存工具.我见过： > System.Web.Caching.Cache不能从WCF使用(据我了解,仅当服务托管在IIS中时才可用,但并非总是如此)> System.Runtime.Caching均可在两者中使用,但仅可从.NET 4获得,但我们的.NET版本为3.5. 有什么建议么？解决方法:您绝对可以在IIS之外使用System.Web.Caching.Cache.只需添加对System.Web的引用就可以了-绝对不是IIS的功能. .NET 1.0和1.1中存在问题,但显然不在2.0...

C#-Redis与应用程序内缓存

使用Redis缓存诸如userId-UserName对,NewsId-NewsDomainName之类的数据有什么好处和缺点？为什么我不应该在creatinf Dictionatries中将这些数据缓存在应用程序内存中？我认为它必须比使用Redis快得多？谢谢！解决方法:根据工作负载的样子,您可能需要一个或另一个,或者同时使用两种缓存策略.为什么？ >进程内缓存速度更快(有利于延迟),更重要的是,它不会产生任何网络流量而受到打击(有利于可扩展性)；>远程缓存(Redis或类似方法)可让...

c# – RabbitMQ CreateConneciton问题 – 在一个应用程序中运行,但在另一个应用程序中运行【代码】

所以这是连接代码.var factory = new ConnectionFactory {HostName = "myserver",UserName = "testuser",Password = "testuserpassword" };using (var connection = factory.CreateConnection())using (var channel = connection.CreateModel()){channel.QueueDeclare(queue: "LOG",durable: false,exclusive: false,autoDelete: false,arguments: null);string message = "Hello World!";var body = Encoding.UTF8.GetBytes(messa...

c# – 在事件查看器中写入应用程序日志【代码】

3小时后收到此消息“找不到源,但无法搜索部分或全部事件日志.无法访问日志：安全性.” 并尝试了几种解决方案,我在这里发帖.是否有一种简洁的方法从我的localhost上运行的WebService(asmx)写入事件日志？我按照msdn上的说明进行了操作,并使用regedit添加了NETWORK SERVICE,并根据其提供了读取权限http://social.msdn.microsoft.com/Forums/en-US/windowsgeneraldevelopmentissues/thread/416098a4-4183-4711-a53b-e10966c9801d/ 这...

c#-如何在“应用程序和服务日志”内部指定事件？【代码】

记录事件后,以下代码片段将触发事件.示例代码可以正常运行,但我要监视的日志实际上是“应用程序和服务日志> Microsoft> Windows>任务计划程序>操作的”. 我要在代码示例中代替“应用程序”插入什么？... EventLog myNewLog = new EventLog("Application", ".", "testEventLogEvent"); myNewLog.EntryWritten += new EntryWrittenEventHandler(MyOnEntryWritten); myNewLog.EnableRaisingEvents = true; ...解决方法...

c#-如何在Azure上查看应用程序日志【代码】

我有一个运行在azure上的aspnetcore 2.1应用程序. 现在,我想查看日志记录信息以调试仅在Azure上发生的问题. 在该应用中,ILogger<>被注入到类中并使用： this._logger.LogInformation(“ constructor ********************************************** ****“); 如果我在VS中运行该应用程序,则可以在调试输出窗口和asp.net核心Web服务器输出窗口中看到输出. 然后,我发布并继续使用Azure并启用日志流并对其进行查看.我确实看到信息出...

C# - 技术教程分类

C# 教程 C# 简介 C# 环境 C# 程序结构 C# 基本语法 C# 数据类型 C# 类型转换 C# 变量 C# 常量 C# 运算符 C# 判断 C# 循环 C# 封装 C# 方法 C# 可空类型 C# 数组（Array） C# 字符串（String） C# 结构体（Struct） C# 枚举（Enum） C# 类（Class） C# 继承 C# 多态性 C# 运算符重载 C# 接口（Interface） C# 命名空间（Namespace） C# 预处理器指令 C# 异常处理 C# 特性（Attribute） C# 反射（Reflection） C# 属性（Property） C# 索引器（Indexer） C# 委托（Delegate） C# 事件（Event） C# 集合（Collection） C# 泛型（Generic） C# 匿名方法 C# 不安全代码 C# 多线程 c# 全部

C# - 最热教程

c#编程连接oracle数据库无法加载DLL(oc...一个适合新手C#程序员编写练习的小项目...C# 异步UDP发送接收数据 C#程序执行时间长和慢查询解决：线程并...c# aspose操作word文档 C#继承讲解以及对象的创建 jquery+ajax+C#实现无刷新操作数据库数...C#精髓 GridView72大绝技学习gridview...c# static的全部用法收集整理 js模拟实现类似c#下的hashtable的简单功...

首页 / C# / c# – 如何从Windows客户端应用程序中使用openAuth？

c# – 如何从Windows客户端应用程序中使用openAuth？

内容导读

内容图文

内容总结

内容备注

内容手机端

【c# – 如何从Windows客户端应用程序中使用openAuth？】教程文章相关的互联网学习教程文章

C# WinForm应用程序降低系统内存占用方法总结【代码】

C#通过窗体应用程序操作数据库（增删改查）【代码】【图】

应用程序使用统计信息 – .NET CORE(C#) WPF界面设计【代码】

C# 控制台应用程序从外部传参运行和调试【代码】【图】

【自动化GUI自动化】C#Windows应用程序识别计算器【代码】

C#获取当前应用程序所在路径及环境变量

C# MVC中按照业务创建多模块web应用程序（DAL、BLL、UI按照业务模块拆分）【图】

应用程序在状态栏展示时间（C#）

C#取得控制台应用程序的根目录方法判断文件夹是否存在，不存在就创建【图】

c#-在WCF和ASP .NET应用程序(.NET 3.5)中都可用的缓存

C#-Redis与应用程序内缓存

c# – RabbitMQ CreateConneciton问题 – 在一个应用程序中运行,但在另一个应用程序中运行【代码】

c# – 在事件查看器中写入应用程序日志【代码】

c#-如何在“应用程序和服务日志”内部指定事件？【代码】

c#-如何在Azure上查看应用程序日志【代码】

WINDOWS - 相关标签

应用程序 - 相关标签

C# - 技术教程分类

C# - 最新教程

C# - 最热教程